Faire un Ping avec WMI Win32_PingStatus

Bien souvent en erreur car toutes les erreurs ne sont pas reconnu, avec ce script tout fonctionne bien

'http://technet.microsoft.com/en-us/library/ee692852.aspx
msgbox PingStatus("Google.com")
msgbox PingStatus("UnSiteQuiExistePas.com")

Function PingStatus(strComputer)

    On Error Resume Next
    strWorkstation = "."
    Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strWorkstation & "\root\cimv2")
    Set colPings = objWMIService.ExecQuery("SELECT * FROM Win32_PingStatus WHERE Address = '" & strComputer & "'")
    For Each objPing in colPings
        Select Case objPing.StatusCode
            Case 0 PingStatus = "Success"
            Case 11001 PingStatus = "Status code 11001 - Buffer Too Small"
            Case 11002 PingStatus = "Status code 11002 - Destination Net Unreachable"
            Case 11003 PingStatus = "Status code 11003 - Destination Host Unreachable"
            Case 11004 PingStatus = _
              "Status code 11004 - Destination Protocol Unreachable"
            Case 11005 PingStatus = "Status code 11005 - Destination Port Unreachable"
            Case 11006 PingStatus = "Status code 11006 - No Resources"
            Case 11007 PingStatus = "Status code 11007 - Bad Option"
            Case 11008 PingStatus = "Status code 11008 - Hardware Error"
            Case 11009 PingStatus = "Status code 11009 - Packet Too Big"
            Case 11010 PingStatus = "Status code 11010 - Request Timed Out"
            Case 11011 PingStatus = "Status code 11011 - Bad Request"
            Case 11012 PingStatus = "Status code 11012 - Bad Route"
            Case 11013 PingStatus = "Status code 11013 - TimeToLive Expired Transit"
            Case 11014 PingStatus = _
              "Status code 11014 - TimeToLive Expired Reassembly"
            Case 11015 PingStatus = "Status code 11015 - Parameter Problem"
            Case 11016 PingStatus = "Status code 11016 - Source Quench"
            Case 11017 PingStatus = "Status code 11017 - Option Too Big"
            Case 11018 PingStatus = "Status code 11018 - Bad Destination"
            Case 11032 PingStatus = "Status code 11032 - Negotiating IPSEC"
            Case 11050 PingStatus = "Status code 11050 - General Failure"
            Case Else PingStatus = "Status code " & objPing.StatusCode & _
               " - Unable to determine cause of failure."
        End Select
    Next

End Function

Lecture d’un fichier ligne par ligne

 

Retourne un tableau de ligne, il suffira de faire une boucle sur 
l’objet ReadFileLine pour lire les ligne une a une

Function ReadFileLine(myFile)
  On error resume Next
  Dim objFSO, strData, strLine, arrLines
  Set objFSO = CreateObject("Scripting.FileSystemObject")
  strData = objFSO.OpenTextFile(myFile,1).ReadAll
  arrLines = Split(strData,vbCrLf)
  ReadFileLine = arrLines
end Function

Procédure – Log dans un fichier texte

Log les informations dans un fichier texte, le mieux est de mettre ce fichier dans le temp de Windows

Public Sub WriteLog(Message)
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set f = fso.OpenTextFile("c:\LOG.txt", 8, True)
    f.WriteLine "[" &  Time & "] - " & Message
    f.Close  
End Sub

Démarrer avec CSCript au lieu de VBScript

Il est des fois très utile de forcer les script en CScript au lieu de VBscript

Public  oWScript : oWScript = Instr(UCase(Wscript.FullName), UCase("CSCRIPT.EXE"))

If oWScript = 0 Then
    Set WshShell = CreateObject("WScript.Shell")
    WshShell.Run "CSCRIPT.EXE """ & WScript.ScriptFullName & """ //Nologo"
    WScript.Quit
End If